Enregistrer vos températures sur votre carte SD

#include <SD.h>
#include <DHT.h>

const int sdCardPinChipSelect = 10;
const char* nomDuFichier = "donnees.csv";
File monFichier;

const int brocheDeBranchementDHT = 8;
const int typeDeDHT = DHT22;
DHT dht(brocheDeBranchementDHT, typeDeDHT);

const long delaiIntervaleDeMesures = 2000; // Intervalle de mesure/enregistrement (exprimé en millis secondes)

void setup() {
  Serial.begin(9600);
  Serial.println(F("Programme DATALOGGER (enregistrement t°/hygro à partir d'un DHT22, et stockage des infos sur carte SD"));

  // Vérification : est-ce que la carte SD est bien accessible depuis l'Arduino ?
  Serial.println(F("Initialisation de la carte SD"));
  if (!SD.begin(sdCardPinChipSelect)) {
    Serial.println(F("Echec de l'initialisation du lecteur de carte SD"));
    while (true);
  }
  Serial.println(F(" reussie !"));

  dht.begin();
}

void loop() {
  // Lecture des données
  float tauxHumidite = dht.readHumidity();
  float temperature = dht.readTemperature();

  // Vérification si données bien reçues
  if (isnan(tauxHumidite) || isnan(temperature)) {
    Serial.println(F("Aucune valeur retournée par le DHT22. Est-il bien branché ?"));
    delay(2000);
    return; // Si aucune valeur n'a été reçue par l'Arduino, on attend 2 secondes, puis on redémarre la fonction loop()
  }

  // Mise en forme de ces données (un seul chiffre après la virgule)
  String tauxHumiditeArrondi = String(tauxHumidite, 1);
  String temperatureArrondie = String(temperature, 1);
  tauxHumiditeArrondi.replace(".", ",");
  temperatureArrondie.replace(".", ",");

  // Affichage des valeurs sur le moniteur série de l'IDE Arduino
  Serial.print("Humidite = ");
  Serial.print(tauxHumiditeArrondi);
  Serial.print(" % - ");
  Serial.print("Temperature = ");
  Serial.print(temperatureArrondie);
  Serial.println(" degre C");

  // Enregistrement de ces données sur la carte SD
  monFichier = SD.open(nomDuFichier, FILE_WRITE);
  if (monFichier) {
    monFichier.print(tauxHumiditeArrondi);
    monFichier.print(";");
    monFichier.println(temperatureArrondie);
    monFichier.close();
    Serial.println(F("Enregistrement reussi en carte SD"));
  }
  else {
    Serial.println(F("Erreur lors de la tentative d'ouverture du fichier en écriture, sur la carte SD"));
  }

  // Temporisation de X secondes (2 sec min, pour que le DHT22 ait le temps de faire ses mesures)
  Serial.println();
  delay(delaiIntervaleDeMesures);
}